Howto send data to dash pro?

Hardware (and firmware) Dash
6

Hi,

Sorry for the delay.

You can send SMS to the Dash/Dash Pro. Here are the steps to do it.

Configuring the Dash/Dash Pro to receive SMS

  1. Upload this Arduino sketch to the Dash/Dash Pro. This is a simple demo of how the Dash identifies an incoming SMS message.

     // EFFECTS: Strips away the length number from the payload as it's not needed.
 String stripOffLengthNumber(String payload) {

   int index = 0;
   while (payload[index] == ',') {
     ++index;
   }
   while (payload[index] != ',') {
     ++index;
   }
   ++index;

   payload.remove(0, index);
   
   return payload;
 }

 void setup() {
   /* Serial Setup */
   SerialUSB.begin(9600); /* USB UART */
   SerialCloud.begin(115200); /* Konekt Cloud */
   delay(4000); /* Delay 4 seconds to wait for Usb Serial to Init.*/

   /* Setup Konekt Dash */
   Dash.begin();
   Dash.pulseLED(100,5000); /* Set the User Led to flash every 5 seconds */

   /* Serial Print Info */
   SerialUSB.println("Konekt Dash SMS Receiving Example Started!");
   SerialUSB.print("Using Boot Version: ");
   SerialUSB.println(Dash.bootVersion()); /* Print Dash Bootloader Version */
   SerialCloud.println("Hello, World!"); /* one-time message */
 }

 String tempBuffer = "";
 String payload = "";
 bool foundSMS = false;

 void loop() {
   char currChar;
   /* the code here will pass data between Cloud<-->UART */

     
   while (SerialCloud.available()) {
     
     currChar = (char)SerialCloud.read();
     
     // check if the current buffer hits the SMSRCVD code.
     if (!foundSMS) {

       if (tempBuffer == "SMSRCVD") {
         foundSMS = true;
       }
     }
     // If it received the SMSRCVD code, the payload will get populated until
     // we get a \n.
     else if (currChar == '\n'){
       
       SerialUSB.println("\nSMS received: ");

       payload = stripOffLengthNumber(payload);
       
       SerialUSB.println(payload);

       // DO SOMETHING WITH SMS HERE.
       
       // reset foundSMS and the payload for the next iteration.
       foundSMS = false;
       payload = "";
     }
     else {
       payload.concat(currChar);
     }

     // Only keep a sliding buffer length of size 7
     // (need to only check for SMSRCVD).
     if (tempBuffer.length() >= 7) {
        tempBuffer.remove(0, 1);
     }

     // add latest char to our buffer.
     tempBuffer.concat(currChar); 
     
     SerialUSB.write(currChar);
   }
   delay(500);
 }

  2. Open up a serial monitor with a baud rate set to 9600. A bunch of events showing what the Dash/Dash Pro is running will appear. You will need to wait for a while to get it initialized and ready to receive SMS. Once an event that says ‘data successfully sent to cloud’, you may proceed to the steps below.

Sending SMS via the Dashboard

  1. Navigate to the Dashboard and click on the ‘Devices’ button.
  2. Choose the device that you want to use by clicking on it, and this will redirect you to a panel showing the device status.
  3. Scroll to the bottom of the page and click (expand) the ‘Send to Device’ tab.
  4. There should be a ‘Send SMS’ form that you can fill up. Fill it up with your message and hit Send.
  5. The SMS will be sent over to the device (this could take some time as well). The message will show up in the serial monitor as 'SMS received: ', followed by the message that you sent to it.

Please feel free to reach out to us again if you have any questions or concerns. Thanks!